Extrair a primeira e a última palavra de um texto

Muitas vezes você deve ter se deparado com a necessidade de obter a primeira e a última palavra de uma célula ou texto no Excel. E é por isso que vamos aprender hoje como extrair a primeira e a última palavra de um texto no Excel com uso de algumas funções.

Infelizmente até o presente momento não existe nenhuma função com esse poder, mas, com a combinação de algumas funções isso será fácil.

Como extrair a primeira palavra de um texto

Em primeiro lugar, suponhamos que eu queira extrair somente o primeiro nome das seguintes cidades:

A primeira cidade Cabo de Santo Agostinho está na primeira célula (A1) e as outras logo abaixo (A2 e A3).

Para obtermos somente o primeiro nome de cada uma, ou seja, Cabo, Cachoeiro e Campo, usamos a seguinte fórmula:

=ESQUERDA(A1;LOCALIZAR(" ";A1;1)-1)

 Onde teremos:

• LOCALIZAR: função do Excel que identifica qual a posição de um texto ou caractere em um mesmo texto.

=LOCALIZAR(TEXTO PROCURADO; NO TEXTO; NÚMERO INICIAL)

• TEXTO PROCURADO: ” “
• NO TEXTO: A1
• NÚMERO INICIAL: 1

Como extrair a última palavra de um texto

Extrair a última palavra é um pouco mais complexo, devido a quantidade de combinações de funções, mas, depois da minha explicação você entenderá facilmente.

Vamos usar novamente o exemplo anterior dos nomes das cidades.

Portanto, queremos obter os nomes Agostinho, Itapemirim e Paulista e para isso temos que utilizar cinco funções do Excel: ARRUMAR, DIREITA, SUBSTITUIR, REPT e NÚM.CARACT.

A fórmula terá a seguinte formação:

=ARRUMAR(DIREITA(SUBSTITUIR(A2;" ";REPT(" ";NÚM.CARACT(A2)));NÚM.CARACT(A2)))

Ufa! Ficou gigante né? Mas, vamos lá!

Explicação

Em primeiro lugar, substituímos todos os espaços entre as palavras pelos espaços iguais ao comprimento do texto, usando a função SUBSTITUIR.

=SUBSTITUIR(A2;" ";REPT(" ";NÚM.CARACT(A2)))

Mas, para que isso funcionasse tivemos que usar também as funções REPT e NÚM.CARACT.

Exemplo:

• 1º Contamos a quantidade de caracteres do texto CABO DE SANTO AGOSTINHO. Função NÚM.CARACT: Resultado 23.
• 2º Repetimos 23 vezes os espaços entre as palavras com a função REPT.
• 3º Substituímos os espaços em branco do texto original pela quantidade que repetimos. No caso de CABO DE SANTO AGOSTINHO, temos 3 espaços, então cada espaço desse foi multiplicado 23 vezes.

Obteremos o resultado abaixo:

Além disso vamos usar a função DIREITA para extrair os caracteres do lado direito com a mesma quantidade de caracteres do texto original.

A fórmula ficará assim:

=DIREITA(SUBSTITUIR(A2;" ";REPT(" ";NÚM.CARACT(A2)));NÚM.CARACT(A2))

Resultado:

Note que teremos espaços em branco antes de cada palavra, ou seja, precisamos resolver isso com a função ARRUMAR da seguinte forma:

=ARRUMAR(DIREITA(SUBSTITUIR(A2;" ";REPT(" ";NÚM.CARACT(A2)));NÚM.CARACT(A2)))

Esta função tem como objetivo retirar espaços em branco antes e depois de cada texto.

Conclusão

Em conclusão. usando as fórmulas acima, você saberá como extrair a primeira e a última palavra de um texto no Excel

A fórmula para a primeira palavra é super fácil e para a última palavra é um pouco complicada, mas você precisa entendê-la uma vez ao iniciar.

Espero que você tenha achado útil essa dica.